おかしいなーと思いつつAdobe Flash Support Centerから
Adobe Flash CS4 Professional Update (10.0.2)　05/13/2009
を落としてきてインストールしたら選べるようになりました。

あれ？前に作ったのってマシン環境新しくする前だったっけ？

var hogeCommand:HogeCommand = new HogeCommand();
var serial:SerialList = new SerialList();

serial.addCommand( hogeCommand );

serial.addCommand( new Func( function():void {
	// コマンドの結果で分岐
	if ( hogeCommand.value ) {
		serial.insertCommand( new Trace("コマンドを挟む"));
	}
}));

serial.execute();

HogeCommandクラスの実行結果を受け取りたいので
インスタンスを先に作っておきます。

var hogeCommand:HogeCommand = new HogeCommand();

今回のキモ「insertCommand」です。
これにより動的にコマンドを挿入させることができます。

	// コマンドの結果で分岐
	if ( hogeCommand.value ) {
		serial.insertCommand( new Trace("コマンドを挟む"));
	}

このやり方についてはIs It So Easy?さんが詳しく書かれています。
this.parentで挿入することも出来るんですねー。

[改訂版]ActionScript3.0プログラミング入門 for Adobe Flash CS4/CS3 ビー・エヌ・エヌ新社 2009-07-23 売り上げランキング : 79902 Amazonで詳しく見る by G-Tools

Resource.as、行 44
1004: 名前空間が見つからないか、コンパイル時定数ではありません。
progression_internal static const $collection:IdGroupCollection = new IdGroupCollection();

いろいろ試して、音声ファイルがリンケージされていると発生することがわかりました。
下記のようにごく一般的なファイルを普通にリンケージしただけえす。

ファイル：testse.wav
クラス：testse
基本クラス：flash.media.Sound

「最初のフレームに書き出し」のチェックを外すとエラーは出ません。

しかし上記チェックを外すわけにもいかず色々試していたら、
Index.asに下記の行を追加したらエラーが出なくなりました。

function hogehoge():void {
	getResourceById("hoge").data;
}

この関数はどこからも呼ばれませんが、記述しておくだけで良いようです。

バグなのか仕様なのかはわかりませんが、公式のフォーラムに報告しておきました。

ActionScript 3.0 エラーアーカイブス コンパイルエラー・コンパイラ警告・ランタイムエラーの解法 大重美幸 ソシム 2009-09-09 売り上げランキング : 83197 おすすめ平均 Amazonで詳しく見る by G-Tools

外部画像を読み込んで一覧表示させるものを作ってまして、
各サムネイル内で読み込むようにしてたんですが、
最初にまとめて読むように変更しました。

というのも、リソースキャッシュのおかげで
画像の流用がすごく簡単に行えるようになったからです。

Progression4で外部ファイルの使い回しを簡単に 》 RuputerFan

リソースキャッシュについては以前かいたこの日記を参照。

複数ファイルの読み込みにはProgressionがLoaderListというクラスを用意しています。

// 読み込む画像一覧
var list:Array = [
	{id:"img_a", url:a.jpg"},
	{id:"img_b", url:b.jpg"},
	{id:"img_c", url:c.jpg"},
];
// 複数ファイル読み込み管理
var loadList:LoaderList = new LoaderList();

// 読み込み開始
loadList.onStart = function():void {
	trace( "まとめて読んじゃうわよ！" );
}
// 読み込み中
loadList.onProgress = function():void {
	trace( this.percent,"%" );
}
// 読み込み完了
loadList.onComplete = function():void{
	trace( "終わったわよ！" );
};
// まとめて読み込み指定
for ( var i:int = 0; i < list.length; i++ ) {
	loadList.addCommand(
		new LoadBitmapData( new URLRequest(list[i].url), {
			cacheAsResource:true, context:new LoaderContext(true),
			resGroup:"images", resId:list[i].id
		} )
	);
}
// 読み込み開始
loadList.execute();

こんな感じにまとめて読み込みます。
読み込みにはLoadBitmapData、LoadSound、LoadSWF、LoadURLなどが使えます。

あるとないとの違い

普通は画像一覧を作る場合、
個々のローダークラスに完了後の処理を書きます。

var bmpLoad1:LoadBitmapData( new URLRequest("a.jpg") );
bmpLoad1.addEventListener( LoadBitmapData.ExecuteEvent, onComplete );

var loadList:LoaderList = new LoaderList();
loadList.addCommand( bmpLoad1 );

しかしリソースキャッシュ機構を組み合わせることで、
個々の終了後の処理は不要になります。
resIdパラメータを指定すれば後からその名前で呼び出せるからです。

	loadList.addCommand(
		new LoadBitmapData( new URLRequest(list[i].url), {
			cacheAsResource:true, context:new LoaderContext(true),
			resGroup:"images", resId:list[i].id
		} )
	);

var bmp:Bitmap = new Bitmap( getResourceById("img_a").data );

複数ファイルのロード管理はCASA Libでも同様のものがありますが、
ProgressionのLoaderListを使う利点はリソースキャッシュにあると思います。

要望というか

LoaderListに要望を出すとしたら並列読み込みのサポートでしょうか。

順次読み込みのほうが回線を圧迫せずにすみますが、
大量にファイルがある場合にやっぱり遅いんですよね。

並列指定も出来ると嬉しいなと。

突然カップヌードルが食べたくなったので貼ってみる。意味はありません。

カップヌードル 売り上げランキング : 71860 おすすめ平均 Amazonで詳しく見る by G-Tools

今日まさにそれでハマっていたので対処法をメモっておきます。

ドキュメントクラス「Index.as」内の下記の箇所を書き換えれば
無効にすることができます。

protected override function atReady():void {
//	manager.sync = true;
	manager.sync = false;

//	manager.goto( manager.syncedSceneId );
	manager.goto( new SceneId('/index') );
}

manager.syncというプロパティが関係するらしいので「false」にします。

manager.syncedSceneIdもURLアンカーによる場所が格納されているぽいので、
移動先も強制的に「/index」にしてしまいます。

もっとエレガントな方法もありそうですが、とりあえずこれで対処できました。

リトルアンカー(限定版) D3PUBLISHER 2009-04-23 売り上げランキング : 7802 おすすめ平均 Amazonで詳しく見る by G-Tools

これまでも外部ファイル（swf、画像、mp3など）を読み込んで使い回す
ということは出来ましたが、それなりに手間がかかりました。

Progression4からはそれらを管理するResource系のクラスが登場し、
かなりシンプルになったようです。

michinoko blogさんで書かれていたことを参考に書いてみました。

package{
import flash.display.Bitmap;
import flash.display.Sprite;
import flash.net.URLRequest;
import flash.system.LoaderContext;
import jp.progression.commands.lists.SerialList;
import jp.progression.commands.Func;
import jp.progression.commands.net.LoadBitmapData;
import jp.progression.data.getResourceById;

public class MyLoadImage extends Sprite{

	public var _id:String;		// リソース格納ID

	/*********************
	 * 外部画像読み込み
	 */
	public function MyLoadImage( url:String, group:String, id:String ){
		_id = id;

		var serial:SerialList = new SerialList();

		// 画像読み込んでキャッシュに格納
		serial.addCommand( new LoadBitmapData( new URLRequest(url), {
			cacheAsResource:true, context:new LoaderContext(true),
			resGroup:group, resId:id
		}));

		// 貼り付け
		serial.addCommand( new Func( attachBitmap ));

		serial.execute();
	}

	/*********************
	 * 画像貼り付け
	 */
	protected function attachBitmap():void {
		// リソースからid指定で画像を取り出す
		var bmp:Bitmap = new Bitmap( getResourceById(_id).data );
		// 貼り付け
		this.addChild( bmp );
	}
}
}

こんな感じでSpriteのサブクラスを作っておいて下記のように呼び出します。
※動作確認してません。

var loadImage:MyLoadImage = new MyLoadImage( "hoge.jpg", "images", "image0" );
this.addChild( loadImage );

例えばこのSpriteをクリックした時に、
idを取得して画像を再利用するなんてことも簡単にできますね。

protected function onImageClick( e:MouseEvent ):void{
	var id:String = e.currentTarget._id;
	var bmpdata:BitmapData = getResourceById(id).data;

	～取り出したBitmapDataを再利用～
}

Progressionのこういった便利ライブラリはとても重宝しています。
開発者の方々に心から感謝！！！

• Progression4の新機能Resourceを試してみる | エントリー | _level0.KAYAC
• michinoko blog ? getResourceByIdとgetResourcesByGroup
• LoadBitmapDataのgroupプロパティ – ActionScript3学習ノート

Progression4のバージョンに注意

上記サンプルでは「resGroup」、「resId」でグループ、IDを指定していますが、
これらは「4.0.1 Public Beta 1.3」から使えるようになります。

自分は1.2だったのでハマりましたｗ

1.3からはWebConfig()の引数も変わったので注意が必要です。
自分はIndex.asで下記のように指定しています。

// 1.2の場合
super( "index", IndexScene,
	new WebConfig( false, false, false ) );
↓
// 1.3の場合
super( "index", IndexScene,
	new WebConfig( "basicLibraryLicense", false, false, false ) );

Adobe Flash CS4 詳細!ActionScript3.0入門ノート[完全改訂版](CD-ROM付) ソーテック社 2009-08-01 売り上げランキング : 9363 おすすめ平均 Amazonで詳しく見る by G-Tools

カスタムコマンドのテンプレートをコピーする

プロジェクトを作成すると「templates」フォルダに様々なテンプレートが作成されます。
「src」フォルダに「MyCommand.as」を複製し、名前を「HokutoCommand.as」に変更します。

※本当は「classes」などのフォルダを作ってまとめたほうが良いのですが割愛します。

中身はこんな感じになっています（余計なコメントは消しています。）

package {
	import jp.progression.casts.*;
	import jp.progression.commands.display.*;
	import jp.progression.commands.lists.*;
	import jp.progression.commands.net.*;
	import jp.progression.commands.tweens.*;
	import jp.progression.commands.*;
	import jp.progression.data.*;
	import jp.progression.events.*;
	import jp.progression.scenes.*;

	public class MyCommand extends Command {

		public function MyCommand( initObject:Object = null ) {
			super( _execute, _interrupt, initObject );
		}

		private function _execute():void {
			executeComplete();
		}

		private function _interrupt():void {
		}

		public override function clone():Command {
			return new MyCommand( this );
		}
	}
}

カスタムコマンドを記述する

それでは北斗百烈拳ならぬ、北斗十烈拳を繰り出すコマンドに書き換えます。
「MyCommand」になっている箇所を「HokutoCommand」に書き換えたり、いろいろ。

package {
	import flash.display.DisplayObjectContainer;
	import flash.display.MovieClip;
	import jp.progression.commands.*;
	import jp.progression.commands.lists.SerialList;

	public class HokutoCommand extends Command {

		private var $myStage:DisplayObjectContainer;

		/*******************************
		 * コンストラクタ
		 * @param	myStage		「あた！」の配置先
		 */
		public function HokutoCommand( myStage:DisplayObjectContainer, initObject:Object = null ) {
			super( _execute, _interrupt, initObject );
			$myStage = myStage;
		}

		/*******************************
		 * 処理実行
		 */
		private function _execute():void {

			// 直列実行コマンド
			var serialList:SerialList = new SerialList();

			// 「あた！」を配置して 0.2秒待つをくり返す
			serialList.addCommand( new Func( addAta ));
			serialList.addCommand( new Wait( 0.2 ));
			～略～
			serialList.addCommand( new Func( addAta ));
			serialList.addCommand( new Wait( 0.2 ));

			// カスタムコマンド終了関数
			serialList.addCommand( new Func( executeComplete ));

			// 終了処理
			serialList.addCommand( new Func( _endExec ));

			// 直列処理開始
			serialList.execute();
		}

		/*******************************
		 * 「あた！」を配置する関数
		 */
		private function addAta():void {

			// ata_mcをランダム位置に貼りつける
			var mc:MovieClip = new ata_mc();
			mc.x = (Math.random() * 300) + 50;
			mc.y = (Math.random() * 200) + 50;

			$myStage.addChild( mc );
		}

		/*******************************
		 * 終了処理
		 */
		private _endExec():void {
			$myStage = null;
		}

		/*******************************
		 * 処理中断
		 */
		private function _interrupt():void {
			// 中断時は終了と同じことをさせる
			_endExec();
		}

		/*******************************
		 * 複製
		 */
		public override function clone():Command {
			return new HokutoCommand( $myStage, this );
		}
	}
}

ポイントの説明

長く見えるかもしれませんがやってることはいたって単純。

		/*******************************
		 * コンストラクタ
		 * @param	myStage		「あた！」の配置先
		 */
		public function HokutoCommand( myStage:DisplayObjectContainer, initObject:Object = null ) {
			super( _execute, _interrupt, initObject );
			$myStage = myStage;
		}

コンストラクタでは「あた！」を配置させる場所を保存しているだけです。
initObjectと、super()は定型文と思ってそのままにしてください。

			// 「あた！」を配置して 0.2秒待つをくり返す
			serialList.addCommand( new Func( addAta ));
			serialList.addCommand( new Wait( 0.2 ));

SerialListは直列処理を実現してくれるクラスです。
Funcクラスは関数を実行するためだけのものです。Commandクラスを継承しています。
addAta()内で「あた！」を配置し、Waitクラスで0.2秒待機させています。

			// カスタムコマンド終了関数
			serialList.addCommand( new Func( executeComplete ));

executeComplete()はとても大切な関数で、
カスタムコマンドの処理が完了したことを上位オブジェクトに通知します。
これを実行しないと上位オブジェクトは次の処理に移りません。

			// 終了処理
			serialList.addCommand( new Func( _endExec ));

		/*******************************
		 * 終了処理
		 */
		private _endExec():void {
			$myStage = null;
		}

executeComplete()で終了の通知は行きますが、
その後は自分でキレイに掃除しなくてはいけません。
やらなくても構いませんがメモリリークの原因になります。

_endExec()（名前は任意）は中断処理でも呼ばれます。
コマンドが中断された際も掃除をしておかないとメモリリークの原因になります。

		/*******************************
		 * 処理中断
		 */
		private function _interrupt():void {
			// 中断時は終了と同じことをさせる
			_endExec();
		}

clone()は同じパラメータを与えられたコマンドを複製しますが、
まぁほとんど使うことはないと思います。
コンストラクタと同じ関数名、引数を与えればよいです。

		/*******************************
		 * 複製
		 */
		public override function clone():Command {
			return new HokutoCommand( $myStage, this );
		}

カスタムコマンドで守るべきこと

実際の処理を書く_execute()と、終了処理を書く_endExec()以外は
ほとんどテンプレートのままで、クラス名にあわせてコンストラクタ名や
引数が変わるくらいです。
（上記２つの関数名は任意）

大切なことは、処理が終わったらexecuteComplete()を実行すること。

その後に終了処理をするということです。
executeComplete()は終了を通知するだけの、いわばdispatchEvent()のようなものです。

カスタムコマンドの呼び出しかた

それでは実際にカスタムコマンドを使ってみましょう。
「IndexScene.as」から呼び出します。

～略～
		/*********************************
		 * ボタン押した
		 */
		private function _onClick( e:MouseEvent ):void {

			// 北斗十烈拳を実行した後、「終わった」を表示
			var serialList:SerialList = new SerialList();
			serialList.addCommand(
				new HokutoCommand( this.container ),
				new Func( _owatta )
			);
			serialList.execute();
		}

		/*********************************
		 * 終わったァ！
		 */
		private function _owatta():void {
			var owatta:MovieClip = new owatta_mc();
			owatta.x = 200;
			owatta.y = 150;

			this.container.addChild( owatta );
		}
～略～

めちゃくちゃシンプルです。
カスタムコマンドを実行しているのはこの行だけ。
「あた！」を配置する場所を指定しています。
initObjectは不要です。

				new HokutoCommand( this.container ),

コンパイルしてみよう

「北斗十烈拳」をクリックすると始まります。

今回のソースファイルをアップしましたので、試してみたい方はどうぞ。
※他の環境で動作するかはテストしてません。

• カスタムコマンド「北斗十烈拳」をダウンロードする。

Adobe Flash CS4 詳細!ActionScript3.0入門ノート[完全改訂版](CD-ROM付) ソーテック社 2009-08-01 売り上げランキング : 15546 おすすめ平均 Amazonで詳しく見る by G-Tools

僕も最初はよくわからなかったのですが、理解してみると
カスタムコマンド無しには制作ができない
と思ってしまうくらいに便利なものです。

Progressionを使い始めて2ヶ月の身ですが
（しかも本来Progressionを使う目的であるシーン管理とかは全く使っていないｗ）
自分なりに理解していることを数回にわけてまとめてみようと思います。

なお本記事で扱うProgressionのバージョンは「4.0.1 Public Beta 1.3」です。

Progressionに興味があるけど最初の一歩が分からないという方は
本家のチュートリアルをご覧になると良いと思います（Ver3対象ですが）。
実に分かりやすく書かれていて、このチュートリアルがあったからこそ
僕もProgressionに手を出すことが出来ました。

• Progression – Framework for Flash > Progression 4 Public Beta
• Progression – Framework for Flash > ドキュメント

カスタムコマンドってなに？

Progressionの魅力のひとつに「直列処理の簡単さ」が挙げられます。

直列処理について説明すると長くなるので
本記事に限定した内容でものすごく簡単に説明すると、
処理Ａが終わるのを待ってから処理Ｂを行う
というものです（だいぶ語弊がありますがｗ）。

例えば……

外部の画像Ａを読む
→読み終わったらSpriteに貼りつける
→貼ったらフェードインさせる
→フェードイン完了したらマウスイベントに反応させる

これを普通に書くとaddEventListenerであちこちに飛び回ることになり、
ソースの見通しが非常に悪くなります。

これらの処理をひとつのクラスとしてまとめたものを
カスタムコマンドと言います。

次の記事では実際に簡単なカスタムコマンドを作ってみます。
眠くなってきたので（現在深夜４時）今日はこのへんでｗ

Web Designing (ウェブデザイニング) 2009年 08月号 [雑誌] 毎日コミュニケーションズ 2009-07-18 売り上げランキング : おすすめ平均 Amazonで詳しく見る by G-Tools