今回は簡単なカスタムコマンドを作ってみます。

カスタムコマンドのテンプレートをコピーする

プロジェクトを作成すると「templates」フォルダに様々なテンプレートが作成されます。
「src」フォルダに「MyCommand.as」を複製し、名前を「HokutoCommand.as」に変更します。

※本当は「classes」などのフォルダを作ってまとめたほうが良いのですが割愛します。

中身はこんな感じになっています（余計なコメントは消しています。）

package {
	import jp.progression.casts.*;
	import jp.progression.commands.display.*;
	import jp.progression.commands.lists.*;
	import jp.progression.commands.net.*;
	import jp.progression.commands.tweens.*;
	import jp.progression.commands.*;
	import jp.progression.data.*;
	import jp.progression.events.*;
	import jp.progression.scenes.*;

	public class MyCommand extends Command {

		public function MyCommand( initObject:Object = null ) {
			super( _execute, _interrupt, initObject );
		}

		private function _execute():void {
			executeComplete();
		}

		private function _interrupt():void {
		}

		public override function clone():Command {
			return new MyCommand( this );
		}
	}
}

カスタムコマンドを記述する

それでは北斗百烈拳ならぬ、北斗十烈拳を繰り出すコマンドに書き換えます。
「MyCommand」になっている箇所を「HokutoCommand」に書き換えたり、いろいろ。

package {
	import flash.display.DisplayObjectContainer;
	import flash.display.MovieClip;
	import jp.progression.commands.*;
	import jp.progression.commands.lists.SerialList;

	public class HokutoCommand extends Command {

		private var $myStage:DisplayObjectContainer;

		/*******************************
		 * コンストラクタ
		 * @param	myStage		「あた！」の配置先
		 */
		public function HokutoCommand( myStage:DisplayObjectContainer, initObject:Object = null ) {
			super( _execute, _interrupt, initObject );
			$myStage = myStage;
		}

		/*******************************
		 * 処理実行
		 */
		private function _execute():void {

			// 直列実行コマンド
			var serialList:SerialList = new SerialList();

			// 「あた！」を配置して 0.2秒待つをくり返す
			serialList.addCommand( new Func( addAta ));
			serialList.addCommand( new Wait( 0.2 ));
			～略～
			serialList.addCommand( new Func( addAta ));
			serialList.addCommand( new Wait( 0.2 ));

			// カスタムコマンド終了関数
			serialList.addCommand( new Func( executeComplete ));

			// 終了処理
			serialList.addCommand( new Func( _endExec ));

			// 直列処理開始
			serialList.execute();
		}

		/*******************************
		 * 「あた！」を配置する関数
		 */
		private function addAta():void {

			// ata_mcをランダム位置に貼りつける
			var mc:MovieClip = new ata_mc();
			mc.x = (Math.random() * 300) + 50;
			mc.y = (Math.random() * 200) + 50;

			$myStage.addChild( mc );
		}

		/*******************************
		 * 終了処理
		 */
		private _endExec():void {
			$myStage = null;
		}

		/*******************************
		 * 処理中断
		 */
		private function _interrupt():void {
			// 中断時は終了と同じことをさせる
			_endExec();
		}

		/*******************************
		 * 複製
		 */
		public override function clone():Command {
			return new HokutoCommand( $myStage, this );
		}
	}
}

ポイントの説明

長く見えるかもしれませんがやってることはいたって単純。

		/*******************************
		 * コンストラクタ
		 * @param	myStage		「あた！」の配置先
		 */
		public function HokutoCommand( myStage:DisplayObjectContainer, initObject:Object = null ) {
			super( _execute, _interrupt, initObject );
			$myStage = myStage;
		}

コンストラクタでは「あた！」を配置させる場所を保存しているだけです。
initObjectと、super()は定型文と思ってそのままにしてください。

			// 「あた！」を配置して 0.2秒待つをくり返す
			serialList.addCommand( new Func( addAta ));
			serialList.addCommand( new Wait( 0.2 ));

SerialListは直列処理を実現してくれるクラスです。
Funcクラスは関数を実行するためだけのものです。Commandクラスを継承しています。
addAta()内で「あた！」を配置し、Waitクラスで0.2秒待機させています。

			// カスタムコマンド終了関数
			serialList.addCommand( new Func( executeComplete ));

executeComplete()はとても大切な関数で、
カスタムコマンドの処理が完了したことを上位オブジェクトに通知します。
これを実行しないと上位オブジェクトは次の処理に移りません。

			// 終了処理
			serialList.addCommand( new Func( _endExec ));

		/*******************************
		 * 終了処理
		 */
		private _endExec():void {
			$myStage = null;
		}

executeComplete()で終了の通知は行きますが、
その後は自分でキレイに掃除しなくてはいけません。
やらなくても構いませんがメモリリークの原因になります。

_endExec()（名前は任意）は中断処理でも呼ばれます。
コマンドが中断された際も掃除をしておかないとメモリリークの原因になります。

		/*******************************
		 * 処理中断
		 */
		private function _interrupt():void {
			// 中断時は終了と同じことをさせる
			_endExec();
		}

clone()は同じパラメータを与えられたコマンドを複製しますが、
まぁほとんど使うことはないと思います。
コンストラクタと同じ関数名、引数を与えればよいです。

		/*******************************
		 * 複製
		 */
		public override function clone():Command {
			return new HokutoCommand( $myStage, this );
		}

カスタムコマンドで守るべきこと

実際の処理を書く_execute()と、終了処理を書く_endExec()以外は
ほとんどテンプレートのままで、クラス名にあわせてコンストラクタ名や
引数が変わるくらいです。
（上記２つの関数名は任意）

大切なことは、処理が終わったらexecuteComplete()を実行すること。

その後に終了処理をするということです。
executeComplete()は終了を通知するだけの、いわばdispatchEvent()のようなものです。

カスタムコマンドの呼び出しかた

それでは実際にカスタムコマンドを使ってみましょう。
「IndexScene.as」から呼び出します。

～略～
		/*********************************
		 * ボタン押した
		 */
		private function _onClick( e:MouseEvent ):void {

			// 北斗十烈拳を実行した後、「終わった」を表示
			var serialList:SerialList = new SerialList();
			serialList.addCommand(
				new HokutoCommand( this.container ),
				new Func( _owatta )
			);
			serialList.execute();
		}

		/*********************************
		 * 終わったァ！
		 */
		private function _owatta():void {
			var owatta:MovieClip = new owatta_mc();
			owatta.x = 200;
			owatta.y = 150;

			this.container.addChild( owatta );
		}
～略～

めちゃくちゃシンプルです。
カスタムコマンドを実行しているのはこの行だけ。
「あた！」を配置する場所を指定しています。
initObjectは不要です。

				new HokutoCommand( this.container ),

コンパイルしてみよう

「北斗十烈拳」をクリックすると始まります。

今回のソースファイルをアップしましたので、試してみたい方はどうぞ。
※他の環境で動作するかはテストしてません。

• カスタムコマンド「北斗十烈拳」をダウンロードする。

Adobe Flash CS4 詳細!ActionScript3.0入門ノート[完全改訂版](CD-ROM付) ソーテック社 2009-08-01 売り上げランキング : 15546 おすすめ平均 Amazonで詳しく見る by G-Tools